nixos/tests/benchexec.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

{ pkgs, lib, ... }:
let
  user = "alice";
in
{
  name = "benchexec";

  nodes.benchexec = {
    imports = [ ./common/user-account.nix ];

    programs.benchexec = {
      enable = true;
      users = [ user ];
    };
  };

  testScript =
    { ... }:
    let
      runexec = lib.getExe' pkgs.benchexec "runexec";
      echo = toString pkgs.benchexec;
      test = lib.getExe (
        pkgs.writeShellApplication rec {
          name = "test";
          meta.mainProgram = name;
          text = "echo '${echo}'";
        }
      );
      wd = "/tmp";
      stdout = "${wd}/runexec.out";
      stderr = "${wd}/runexec.err";
    in
    ''
      start_all()
      benchexec.wait_for_unit("multi-user.target")
      benchexec.succeed(''''\
          systemd-run \
            --property='StandardOutput=file:${stdout}' \
            --property='StandardError=file:${stderr}' \
            --unit=runexec --wait --user --machine='${user}@' \
            --working-directory ${wd} \
          '${runexec}' \
            --debug \
            --read-only-dir / \
            --hidden-dir /home \
            --no-container \
            -- '${test}' \
      '''')
      benchexec.succeed("grep -s '${echo}' ${wd}/output.log")
      benchexec.succeed("test \"$(grep -Ec '((start|wall|cpu)time|memory)=' ${stdout})\" = 4")
      benchexec.succeed("! grep -E '(WARNING|ERROR)' ${stderr}")
    '';

  interactive.nodes.benchexec.services.kmscon = {
    enable = true;
    fonts = [
      {
        name = "Fira Code";
        package = pkgs.fira-code;
      }
    ];
  };
}