nixos/tests/agda/base.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

{ pkgs, ... }:

let
  hello-world = ./files/HelloWorld.agda;
in
{
  name = "agda";
  meta = with pkgs.lib.maintainers; {
    maintainers = [
      alexarice
      turion
    ];
  };

  nodes.machine =
    { pkgs, ... }:
    {
      environment.systemPackages = [
        (pkgs.agda.withPackages {
          pkgs = p: [ p.standard-library ];
        })
      ];
      virtualisation.memorySize = 2000; # Agda uses a lot of memory
    };

  testScript = ''
    # agda and agda-mode are in path
    machine.succeed("agda --version")

    # Minimal script that typechecks
    machine.succeed("touch TestEmpty.agda")
    machine.succeed("agda TestEmpty.agda")

    # Hello world
    machine.succeed(
        "cp ${hello-world} HelloWorld.agda"
    )
    machine.succeed("agda -l standard-library -i . -c HelloWorld.agda")
    # Check execution
    assert "Hello World!" in machine.succeed(
        "./HelloWorld"
    ), "HelloWorld does not run properly"
  '';
}