nixos/modules/virtualisation/lxcfs.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# LXC Configuration

{
  config,
  lib,
  pkgs,
  ...
}:

let
  cfg = config.virtualisation.lxc.lxcfs;
in
{
  meta = {
    teams = [ lib.teams.lxc ];
  };

  ###### interface
  options.virtualisation.lxc.lxcfs = {
    enable = lib.mkOption {
      type = lib.types.bool;
      default = false;
      description = ''
        This enables LXCFS, a FUSE filesystem for LXC.
        To use lxcfs in include the following configuration in your
        container configuration:
        ```
        virtualisation.lxc.defaultConfig = "lxc.include = ''${pkgs.lxcfs}/share/lxc/config/common.conf.d/00-lxcfs.conf";
        ```
      '';
    };
  };

  ###### implementation
  config = lib.mkIf cfg.enable {
    systemd.services.lxcfs = {
      description = "FUSE filesystem for LXC";
      wantedBy = [ "multi-user.target" ];
      before = [ "lxc.service" ];
      restartIfChanged = false;
      serviceConfig = {
        ExecStartPre = "${pkgs.coreutils}/bin/mkdir -p /var/lib/lxcfs";
        ExecStart = "${pkgs.lxcfs}/bin/lxcfs /var/lib/lxcfs";
        ExecStopPost = "-${pkgs.fuse3}/bin/fusermount3 -u /var/lib/lxcfs";
        KillMode = "process";
        Restart = "on-failure";
      };
    };
  };
}