blob: dbd1a89b5ffd3459bb1363a8f832dbe64696525e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
{
config,
lib,
pkgs,
...
}:
let
cfg = config.services.xscreensaver;
in
{
options.services.xscreensaver = {
enable = lib.mkEnableOption "xscreensaver user service";
package = lib.mkPackageOption pkgs "xscreensaver" { };
hooks = lib.mkOption {
type = with lib.types; attrsOf lines;
description = ''
An attrset of events and commands to run upon each event.
Refer to <https://www.jwz.org/xscreensaver/man3.html> for supported events.
'';
defaultText = lib.literalExpression "{ }";
default = { };
example = lib.literalExpression ''
# Reconfigure autorandr on screen wake up
{
"RUN" = "''${lib.getExe pkgs.autorandr} --change --ignore-lid";
};
'';
};
};
config = lib.mkIf cfg.enable {
# Make xscreensaver-auth setuid root so that it can (try to) prevent the OOM
# killer from unlocking the screen.
security.wrappers.xscreensaver-auth = {
setuid = true;
owner = "root";
group = "root";
source = "${pkgs.xscreensaver}/libexec/xscreensaver/xscreensaver-auth";
};
systemd.user.services = {
xscreensaver = {
enable = true;
description = "XScreenSaver";
after = [ "graphical-session-pre.target" ];
partOf = [ "graphical-session.target" ];
wantedBy = [ "graphical-session.target" ];
path = [ cfg.package ];
serviceConfig.ExecStart = "${cfg.package}/bin/xscreensaver -no-splash";
};
xscreensaver-hooks = lib.mkIf (cfg.enable && cfg.hooks != { }) {
enable = true;
description = "Run commands on XScreenSaver events";
after = [
"graphical-session.target"
"xscreensaver.service"
];
partOf = [ "graphical-session.target" ];
wantedBy = [ "graphical-session.target" ];
path = [ cfg.package ];
serviceConfig = {
Restart = "always";
};
script =
let
handlers = lib.concatMapAttrsStringSep "\n" (event: action: ''
"${event}")
( ${action}
)
;;
'') cfg.hooks;
in
''
xscreensaver-command -watch | while read event rest; do
echo "XScreenSaver handler script got \"$event\""
case $event in
${handlers}
esac
done
'';
};
};
};
meta.maintainers = with lib.maintainers; [
vancluever
];
}
|
