blob: 675a6314426b30b1640e5608e2916f733aea94f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
{
config,
lib,
pkgs,
...
}:
let
cfg = config.services.rustfs;
in
{
meta.maintainers = with lib.maintainers; [
marcel
];
options.services.rustfs = {
enable = lib.mkEnableOption "RustFS Object Storage Server";
package = lib.mkPackageOption pkgs "rustfs" { };
user = lib.mkOption {
type = lib.types.str;
default = "rustfs";
description = "The user RustFS should run as.";
};
group = lib.mkOption {
type = lib.types.str;
default = "rustfs";
description = "The group RustFS should run as.";
};
settings = lib.mkOption {
default = { };
description = ''
Options for RustFS configuration. Refer to
<https://docs.rustfs.com/installation/linux/single-node-single-disk.html#_5-configure-environment-variables>
for details on supported values.
'';
example = lib.literalExpression ''
{
RUSTFS_CONSOLE_ENABLE = "true";
RUSTFS_VOLUMES = "/mnt/rustfs";
}
'';
type = lib.types.submodule {
freeformType = lib.types.attrsOf (
lib.types.oneOf [
lib.types.str
lib.types.int
]
);
options = {
RUSTFS_VOLUMES = lib.mkOption {
type = lib.types.path;
default = "/var/lib/rustfs";
description = "The directory where RustFS stores it's data.";
};
};
};
};
environmentFile = lib.mkOption {
type = lib.types.str;
description = "Path to environment file containing secrets like RUSTFS_ACCESS_KEY or RUSTFS_SECRET_KEY.";
};
};
config = lib.mkIf cfg.enable {
assertions = [
{
assertion = !(cfg.settings ? RUSTFS_ACCESS_KEY);
message = "RUSTFS_ACCESS_KEY must not be set in services.rustfs.settings. Use environmentFile instead.";
}
{
assertion = !(cfg.settings ? RUSTFS_SECRET_KEY);
message = "RUSTFS_SECRET_KEY must not be set in services.rustfs.settings. Use environmentFile instead.";
}
];
systemd = {
tmpfiles.settings."10-rustfs".${cfg.settings.RUSTFS_VOLUMES}.d = {
inherit (cfg) user group;
};
# https://docs.rustfs.com/installation/linux/single-node-single-disk.html#_6-configure-system-service
services.rustfs = {
description = "RustFS Object Storage Server";
documentation = [ "https://rustfs.com/docs/" ];
after = [ "network-online.target" ];
wants = [ "network-online.target" ];
wantedBy = [ "multi-user.target" ];
environment = cfg.settings;
preStart = ''
if [ -z "$RUSTFS_ACCESS_KEY" ] || [ -z "$RUSTFS_SECRET_KEY" ]; then
echo "RustFS uses well-known default values for RUSTFS_ACCESS_KEY and RUSTFS_SECRET_KEY,"
echo "please configure them using services.rustfs.environmentFile."
exit 1
fi
'';
serviceConfig = {
Type = "notify";
NotifyAccess = "main";
User = cfg.user;
Group = cfg.group;
EnvironmentFile = cfg.environmentFile;
ExecStart = lib.getExe cfg.package;
LimitNOFILE = 1048576;
LimitNPROC = 32768;
TasksMax = "infinity";
Restart = "always";
RestartSec = "10s";
OOMScoreAdjust = "-1000";
SendSIGKILL = false;
TimeoutStartSec = "30s";
TimeoutStopSec = "30s";
NoNewPrivileges = true;
ProtectHome = true;
PrivateTmp = true;
PrivateDevices = true;
ProtectClock = true;
ProtectKernelTunables = true;
ProtectKernelModules = true;
ProtectControlGroups = true;
RestrictSUIDSGID = true;
RestrictRealtime = true;
};
};
};
users = {
users.${cfg.user} = {
isSystemUser = true;
inherit (cfg) group;
};
groups.${cfg.group} = { };
};
};
}
|
