blob: 96d38864875b4ef9ca681efe5f4587ed35254db9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
|
{
config,
lib,
pkgs,
...
}:
let
inherit (lib)
escapeShellArgs
filter
hasPrefix
makeBinPath
mapAttrsToList
mkEnableOption
mkIf
mkOption
mkPackageOption
optional
optionals
;
format = pkgs.formats.toml { };
in
{
options =
let
inherit (lib.types)
bool
enum
lines
listOf
str
;
in
{
services.yggdrasil-jumper = {
enable = mkEnableOption "the Yggdrasil Jumper system service";
retrieveListenAddresses = mkOption {
type = bool;
default = true;
description = ''
Automatically retrieve listen addresses from the Yggdrasil router configuration.
See `yggdrasil_listen` option in Yggdrasil Jumper configuration.
'';
};
appendListenAddresses = mkOption {
type = bool;
default = true;
description = ''
Append Yggdrasil router configuration with listeners on loopback
addresses (`127.0.0.1`) and preselected ports to support peering
using client-server protocols like `quic` and `tls`.
See `Listen` option in Yggdrasil router configuration.
'';
};
detectWireguard = mkOption {
type = bool;
default = true;
description = ''
Control whether `settings.wireguard = true` should automatically
provide CAP_NET_ADMIN capability and make the necessary packages
available to Yggdrasil Jumper service.
'';
};
settings = mkOption {
type = format.type;
default = { };
example = {
listen_port = 9999;
whitelist = [ "<IPv6 address of a remote node>" ];
wireguard = true;
};
description = ''
Configuration for Yggdrasil Jumper as a Nix attribute set.
'';
};
extraConfig = mkOption {
type = lines;
default = "";
example = ''
listen_port = 9999;
whitelist = [
"<IPv6 address of a remote node>"
];
'';
description = ''
Configuration for Yggdrasil Jumper in plaintext.
'';
};
package = mkPackageOption pkgs "yggdrasil-jumper" { };
logLevel = mkOption {
type = enum [
"off"
"error"
"warn"
"info"
"debug"
"trace"
];
default = "info";
description = ''
Set logging verbosity for Yggdrasil Jumper.
'';
};
extraArgs = mkOption {
type = listOf str;
default = [ ];
description = ''
Extra command line arguments for Yggdrasil Jumper.
'';
};
};
};
config =
let
cfg = config.services.yggdrasil-jumper;
wg = cfg.detectWireguard && (cfg.settings ? wireguard) && cfg.settings.wireguard;
wgExtraPkgs = optionals wg (
with pkgs;
[
iproute2
iptables
wireguard-tools
conntrack-tools
]
);
# Generate, concatenate and validate config file
jumperSettings = format.generate "yggdrasil-jumper-settings" cfg.settings;
jumperExtraConfig = pkgs.writeText "yggdrasil-jumper-extra-config" cfg.extraConfig;
jumperConfig = pkgs.runCommand "yggdrasil-jumper-config" { } ''
export PATH="${makeBinPath wgExtraPkgs}:$PATH"
cat ${jumperSettings} ${jumperExtraConfig} \
| tee $out \
| ${cfg.package}/bin/yggdrasil-jumper --validate --config -
'';
in
mkIf cfg.enable {
assertions = [
{
assertion = config.services.yggdrasil.enable;
message = "`services.yggdrasil.enable` must be true for `yggdrasil-jumper` to operate";
}
];
services.yggdrasil.settings.Listen =
let
# By default linux dynamically allocates ports in range 32768..60999
# `sysctl net.ipv4.ip_local_port_range`
# See: https://xkcd.com/221/
prot_port = {
"tls" = 11814;
"quic" = 11814;
};
in
mkIf (cfg.retrieveListenAddresses && cfg.appendListenAddresses) (
mapAttrsToList (prot: port: "${prot}://127.0.0.1:${toString port}") prot_port
);
services.yggdrasil-jumper.settings = {
yggdrasil_admin_listen = [ "unix:///run/yggdrasil/yggdrasil.sock" ];
yggdrasil_listen = mkIf cfg.retrieveListenAddresses (
filter (a: !hasPrefix "tcp://" a) config.services.yggdrasil.settings.Listen
);
};
systemd.services.yggdrasil-jumper = {
description = "Yggdrasil Jumper Service";
after = [ "yggdrasil.service" ];
unitConfig.BindsTo = [ "yggdrasil.service" ];
wantedBy = [ "multi-user.target" ];
path = wgExtraPkgs;
serviceConfig = {
User = "yggdrasil";
DynamicUser = true;
# TODO: Remove this delay after support for proper startup notification lands in `yggdrasil-go`
ExecStartPre = "${pkgs.coreutils}/bin/sleep 5";
ExecStart = escapeShellArgs (
[
"${cfg.package}/bin/yggdrasil-jumper"
"--loglevel"
"${cfg.logLevel}"
"--config"
"${jumperConfig}"
]
++ cfg.extraArgs
);
KillSignal = "SIGINT";
MemoryDenyWriteExecute = true;
ProtectControlGroups = true;
ProtectHome = "tmpfs";
RestrictAddressFamilies = [
"AF_UNIX"
"AF_INET"
"AF_INET6"
]
++ optional wg "AF_NETLINK";
RestrictNamespaces = true;
RestrictRealtime = true;
AmbientCapabilities = optional wg "CAP_NET_ADMIN";
CapabilityBoundingSet = optional wg "CAP_NET_ADMIN";
SystemCallArchitectures = "native";
SystemCallFilter = [
"@system-service"
"~@privileged"
];
};
};
environment.systemPackages = [ cfg.package ];
};
meta.maintainers = with lib.maintainers; [ one-d-wide ];
}
|
