blob: f4296396967ca495c36b72bb4e6f8763f6261c2f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
|
{
config,
lib,
pkgs,
...
}:
with lib;
let
cfg = config.services.shairport-sync;
configFormat = pkgs.formats.libconfig { };
configFile = configFormat.generate "shairport-sync.conf" cfg.settings;
in
{
###### interface
options = {
services.shairport-sync = {
enable = mkOption {
type = types.bool;
default = false;
description = ''
Enable the shairport-sync daemon.
Running with a local system-wide or remote pulseaudio server
is recommended.
'';
};
package = lib.options.mkPackageOption pkgs "shairport-sync" { };
settings = mkOption {
type = configFormat.type;
default = {
general.output_backend = "pulseaudio";
diagnostics.log_verbosity = 1;
};
example = {
general = {
name = "NixOS Shairport";
output_backend = "pipewire";
};
metadata = {
enabled = "yes";
include_cover_art = "yes";
cover_art_cache_directory = "/tmp/shairport-sync/.cache/coverart";
pipe_name = "/tmp/shairport-sync-metadata";
pipe_timeout = 5000;
};
mqtt = {
enabled = "yes";
hostname = "mqtt.server.domain.example";
port = 1883;
publish_parsed = "yes";
publish_cover = "yes";
};
};
description = ''
Configuration options for Shairport-Sync.
See the example [shairport-sync.conf][example-file] for possible options.
[example-file]: https://github.com/mikebrady/shairport-sync/blob/master/scripts/shairport-sync.conf
'';
};
arguments = mkOption {
type = types.str;
default = "";
description = ''
Arguments to pass to the daemon. Defaults to a local pulseaudio
server.
'';
};
openFirewall = mkOption {
type = types.bool;
default = false;
description = ''
Whether to automatically open ports in the firewall.
'';
};
user = mkOption {
type = types.str;
default = "shairport";
description = ''
User account name under which to run shairport-sync. The account
will be created.
'';
};
group = mkOption {
type = types.str;
default = "shairport";
description = ''
Group account name under which to run shairport-sync. The account
will be created.
'';
};
};
};
###### implementation
config = mkIf config.services.shairport-sync.enable {
assertions = [
{
assertion = config.services.shairport-sync.settings.general.output_backend or null != "pw";
message = "shairport-sync 5.0 renamed the pipewire backend from 'pw' to 'pipewire'";
}
{
assertion = config.services.shairport-sync.settings.general.output_backend or null != "pa";
message = "shairport-sync 5.0 renamed the pulseaudio backend from 'pa' to 'pulseaudio'";
}
];
services.avahi.enable = true;
services.avahi.publish.enable = true;
services.avahi.publish.userServices = true;
services.shairport-sync.settings = {
general.output_backend = lib.mkDefault "pulseaudio";
diagnostics.log_verbosity = lib.mkDefault 1;
};
users = {
users.${cfg.user} = {
description = "Shairport user";
isSystemUser = true;
createHome = true;
home = "/var/lib/shairport-sync";
group = cfg.group;
extraGroups = [
"audio"
]
++ optional (config.services.pulseaudio.enable || config.services.pipewire.pulse.enable) "pulse";
};
groups.${cfg.group} = { };
};
networking.firewall = mkIf cfg.openFirewall {
allowedTCPPorts = [ 5000 ];
allowedUDPPortRanges = [
{
from = 6001;
to = 6011;
}
];
};
systemd.services.shairport-sync = {
description = "shairport-sync";
after = [
"network.target"
"avahi-daemon.service"
];
wantedBy = [ "multi-user.target" ];
serviceConfig = {
User = cfg.user;
Group = cfg.group;
ExecStart = "${lib.getExe cfg.package} ${cfg.arguments}";
Restart = "on-failure";
RuntimeDirectory = "shairport-sync";
};
};
environment = {
systemPackages = [ cfg.package ];
etc."shairport-sync.conf".source = configFile;
};
};
}
|
