blob: 807d169ac6fc5fa31c9606d10dfe273b9903238c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
{
config,
lib,
pkgs,
...
}:
let
cfg = config.services.logiops;
configFormat = pkgs.formats.libconfig { };
configFile = configFormat.generate "logid.cfg" cfg.config;
in
{
options = {
services.logiops = {
enable = lib.mkEnableOption "LogiOps, a unofficial userspace driver for HID++ Logitech devices";
package = lib.mkPackageOption pkgs "logiops" { };
config = lib.mkOption {
type = configFormat.type;
default = { };
example = lib.literalExpression ''
devices = [
{
name = "Wireless Mouse MX Master";
dpi = 1000;
smartshift =
{
on = true;
threshold = 30;
torque = 50;
};
}
];
'';
description = ''
The standard libconfig-style config for LogiOps.
'';
};
};
};
config = lib.mkIf cfg.enable {
environment.systemPackages = [ cfg.package ];
services.dbus.packages = [ cfg.package ];
systemd = {
packages = [ cfg.package ];
services.logid = {
wantedBy = [ "graphical.target" ];
serviceConfig.ExecStart = [
""
"${lib.getExe cfg.package} -c ${configFile}"
];
};
};
};
meta.maintainers = with lib.maintainers; [ bokicoder ];
}
|
