blob: 9bedb81736e540601aa50bcd235d45dc2ed30137 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
{
config,
lib,
pkgs,
...
}:
let
pkg = pkgs.haste-server;
cfg = config.services.haste-server;
format = pkgs.formats.json { };
in
{
options.services.haste-server = {
enable = lib.mkEnableOption "haste-server";
openFirewall = lib.mkEnableOption "firewall passthrough for haste-server";
settings = lib.mkOption {
description = ''
Configuration for haste-server.
For documentation see [project readme](https://github.com/toptal/haste-server#settings)
'';
type = format.type;
};
};
config = lib.mkIf (cfg.enable) {
networking.firewall.allowedTCPPorts = lib.mkIf (cfg.openFirewall) [ cfg.settings.port ];
services.haste-server = {
settings = {
host = lib.mkDefault "::";
port = lib.mkDefault 7777;
keyLength = lib.mkDefault 10;
maxLength = lib.mkDefault 400000;
staticMaxAge = lib.mkDefault 86400;
recompressStaticAssets = lib.mkDefault false;
logging = lib.mkDefault [
{
level = "verbose";
type = "Console";
colorize = true;
}
];
keyGenerator = lib.mkDefault {
type = "phonetic";
};
rateLimits = {
categories = {
normal = {
totalRequests = lib.mkDefault 500;
every = lib.mkDefault 60000;
};
};
};
storage = lib.mkDefault {
type = "file";
};
documents = {
about = lib.mkDefault "${pkg}/share/haste-server/about.md";
};
};
};
systemd.services.haste-server = {
wantedBy = [ "multi-user.target" ];
requires = [ "network.target" ];
after = [ "network.target" ];
serviceConfig = {
User = "haste-server";
DynamicUser = true;
StateDirectory = "haste-server";
WorkingDirectory = "/var/lib/haste-server";
ExecStart = "${pkg}/bin/haste-server ${format.generate "config.json" cfg.settings}";
};
path = with pkgs; [
pkg
coreutils
];
};
};
}
|
