blob: 048dd343202e13347aafae56e1b7d88b2290227d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{
config,
lib,
pkgs,
...
}:
let
cfg = config.services.espanso;
in
{
meta = {
maintainers = with lib.maintainers; [
n8henrie
numkem
];
};
options = {
services.espanso = {
enable = lib.mkEnableOption "Espanso";
package = lib.mkPackageOption pkgs "espanso" {
example = "pkgs.espanso-wayland";
};
extraPackages = lib.mkOption {
type = lib.types.listOf lib.types.package;
default = [ ];
example = lib.literalExpression "with pkgs; [ bash curl python3 ];";
description = "Extra packages to be added to Espanso service path.";
};
};
};
config = lib.mkIf cfg.enable {
security.wrappers.espanso = lib.mkIf (cfg.package.waylandSupport or false) {
capabilities = "cap_dac_override+p";
owner = "root";
group = "root";
source = lib.getExe (cfg.package.override { securityWrapperPath = config.security.wrapperDir; });
};
systemd.user.services.espanso = {
description = "Espanso daemon";
serviceConfig = {
ExecStart = "${
if (cfg.package.waylandSupport or false) then
"${config.security.wrapperDir}/espanso"
else
lib.getExe cfg.package
} daemon";
Restart = "on-failure";
};
wantedBy = [ "graphical-session.target" ];
path = cfg.extraPackages;
};
environment.systemPackages = [ cfg.package ];
};
}
|
