blob: 530acc504f90821782084355d1aecc40203f5568 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
{
config,
lib,
pkgs,
...
}:
let
cfg = config.services.monetdb;
in
{
meta.maintainers = with lib.maintainers; [ StillerHarpo ];
###### interface
options = {
services.monetdb = {
enable = lib.mkEnableOption "the MonetDB database server";
package = lib.mkPackageOption pkgs "monetdb" { };
user = lib.mkOption {
type = lib.types.str;
default = "monetdb";
description = "User account under which MonetDB runs.";
};
group = lib.mkOption {
type = lib.types.str;
default = "monetdb";
description = "Group under which MonetDB runs.";
};
dataDir = lib.mkOption {
type = lib.types.path;
default = "/var/lib/monetdb";
description = "Data directory for the dbfarm.";
};
port = lib.mkOption {
type = lib.types.port;
default = 50000;
description = "Port to listen on.";
};
listenAddress = lib.mkOption {
type = lib.types.str;
default = "127.0.0.1";
example = "0.0.0.0";
description = "Address to listen on.";
};
};
};
###### implementation
config = lib.mkIf cfg.enable {
users.users.monetdb = lib.mkIf (cfg.user == "monetdb") {
uid = config.ids.uids.monetdb;
group = cfg.group;
description = "MonetDB user";
home = cfg.dataDir;
createHome = true;
};
users.groups.monetdb = lib.mkIf (cfg.group == "monetdb") {
gid = config.ids.gids.monetdb;
members = [ cfg.user ];
};
environment.systemPackages = [ cfg.package ];
systemd.services.monetdb = {
description = "MonetDB database server";
wantedBy = [ "multi-user.target" ];
after = [ "network.target" ];
path = [ cfg.package ];
unitConfig.RequiresMountsFor = "${cfg.dataDir}";
serviceConfig = {
User = cfg.user;
Group = cfg.group;
ExecStart = "${cfg.package}/bin/monetdbd start -n ${cfg.dataDir}";
ExecStop = "${cfg.package}/bin/monetdbd stop ${cfg.dataDir}";
};
preStart = ''
if [ ! -e ${cfg.dataDir}/.merovingian_properties ]; then
# Create the dbfarm (as cfg.user)
${cfg.package}/bin/monetdbd create ${cfg.dataDir}
fi
# Update the properties
${cfg.package}/bin/monetdbd set port=${toString cfg.port} ${cfg.dataDir}
${cfg.package}/bin/monetdbd set listenaddr=${cfg.listenAddress} ${cfg.dataDir}
'';
};
};
}
|
