blob: 5f7ce4fa5a4f1d42235f4d502497f94be4aba02e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
{
config,
lib,
pkgs,
...
}:
let
cfg = config.services.squeezelite;
serviceDeps = [
"network.target"
"sound.target"
]
++ lib.optionals cfg.pulseaudio.enable (
if config.services.pulseaudio.systemWide then
[ "pulseaudio.service" ]
else
[
"pipewire.service"
"pipewire-pulse.socket"
]
);
in
{
imports = [
(lib.mkRenamedOptionModule
[ "services" "squeezelite" "pulseAudio" ]
[ "services" "squeezelite" "pulseaudio" "enable" ]
)
(lib.mkRenamedOptionModule
[ "services" "squeezelite" "extraArguments" ]
[ "services" "squeezelite" "extraArgs" ]
)
];
options.services.squeezelite = {
enable = lib.mkEnableOption "Squeezelite, a software Squeezebox emulator";
package = lib.mkPackageOption pkgs "squeezelite" { } // {
default = if cfg.pulseaudio.enable then pkgs.squeezelite-pulse else pkgs.squeezelite;
defaultText = lib.literalExpression "if config.services.squeezelite.pulseaudio.enable then pkgs.squeezelite-pulse else pkgs.squeezelite";
};
name = lib.mkOption {
type = lib.types.nullOr lib.types.str;
description = "name to report to server";
default = null;
};
mutableName = lib.mkOption {
type = lib.types.bool;
description = "store name in file, controllable by server";
default = cfg.name == null;
defaultText = lib.literalExpression "config.services.squeezelite.name == null";
};
pulseaudio = {
enable = lib.mkEnableOption "pulseaudio support";
group = lib.mkOption {
type = lib.types.str;
description = "group for accessing to pulseaudio socket";
default = if config.services.pulseaudio.systemWide then "pulse-access" else "pipewire";
defaultText = lib.literalExpression ''if config.services.pulseaudio.systemWide then "pulse-access" else "pipewire"'';
};
};
extraArgs = lib.mkOption {
default = "";
type = lib.types.str;
description = ''
Additional command line arguments to pass to Squeezelite.
'';
};
};
config = lib.mkIf cfg.enable {
assertions = [
{
assertion = cfg.name == null || !cfg.mutableName;
message = "'services.squeezelite.name' and 'services.squeezelite.mutableName' are mutually exclusive";
}
{
assertion =
!cfg.pulseaudio.enable
|| (
(config.services.pulseaudio.enable && config.services.pulseaudio.systemWide)
|| (
config.services.pipewire.enable
&& config.services.pipewire.pulse.enable
&& config.services.pipewire.systemWide
)
);
message = ''
`services.squeezelite.pulseaudio.enable = true' requires a system-wide Pulseaudio server. Either:
- `services.pulseaudio.enable = true' and `services.pulseaudio.systemWide = true'
or
- `services.pipewire.enable = true', `services.pipewire.pulse.enable = true', and `services.pipewire.systemWide = true'
should be set.
'';
}
];
systemd.services.squeezelite = {
wantedBy = [
"multi-user.target"
# try and start squeezelite if it isn't already, e.g. a sound card plugged in
"sound.target"
];
after = serviceDeps;
requires = serviceDeps;
description = "Software Squeezebox emulator";
environment = {
XDG_CONFIG_HOME = "%S/squeezelite/.config";
XDG_RUNTIME_DIR = "%t/squeezelite";
};
serviceConfig = {
ExecStartPre = [
# print available interfaces
"${lib.getExe cfg.package} -l"
]
++ lib.optionals (!cfg.pulseaudio.enable) [
# print available alsa controls
"${lib.getExe cfg.package} -L"
];
ExecStart = "${lib.getExe cfg.package} ${
lib.optionalString (cfg.name != null) "-n ${cfg.name} "
}${lib.optionalString cfg.mutableName "-N %S/squeezelite/player-name "}${cfg.extraArgs}";
DynamicUser = true;
RuntimeDirectory = "squeezelite";
RuntimeDirectoryMode = "0700";
StateDirectory = "squeezelite";
StateDirectoryMode = "0700";
SupplementaryGroups = [
"audio"
]
++ lib.optionals cfg.pulseaudio.enable [
cfg.pulseaudio.group
];
TimeoutStopSec = "5";
};
};
};
}
|
