blob: be69ad9ba057e96b2cdc806637339d9ece544f01 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
|
{
config,
lib,
pkgs,
utils,
...
}:
let
inherit (lib)
mkIf
mkEnableOption
mkOption
mkPackageOption
types
;
inherit (types)
bool
listOf
enum
str
;
cfg = config.services.music-assistant;
finalPackage = cfg.package.override {
inherit (cfg) providers;
};
# YouTube Music needs deno with JIT to solve yt-dlp challenges
useYTMusic = lib.elem "ytmusic" cfg.providers;
in
{
meta.buildDocsInSandbox = false;
options.services.music-assistant = {
enable = mkEnableOption "Music Assistant";
package = mkPackageOption pkgs "music-assistant" { };
extraOptions = mkOption {
type = listOf str;
default = [
"--config"
"/var/lib/music-assistant"
];
example = [
"--log-level"
"DEBUG"
];
description = ''
List of extra options to pass to the music-assistant executable.
'';
};
openFirewall = lib.mkOption {
type = bool;
default = false;
description = ''
Whether to open required ports for the configured providers.
Currently airplay and sendspin need port to be opened to function.
'';
};
providers = mkOption {
type = listOf (enum cfg.package.providerNames);
default = [ ];
example = [
"opensubsonic"
"snapcast"
];
description = ''
List of provider names for which dependencies will be installed.
'';
};
};
config = mkIf cfg.enable {
networking.firewall = lib.mkIf cfg.openFirewall {
allowedTCPPorts =
lib.optional cfg.enable 8097 # Music Assistant stream port
++ lib.optional (lib.elem "airplay" cfg.providers) 7000
++ lib.optional (lib.elem "sendspin" cfg.providers) 8927
++ lib.optional (lib.elem "snapcast" cfg.providers) 1780
++ lib.optionals (lib.elem "squeezelite" cfg.providers) [
# https://lyrion.org/reference/slimproto-protocol/
3483 # Slimproto control
# https://lyrion.org/reference/cli/using-the-cli/
9000 # Slimproto JSON-RPC
9090 # Slimproto CLI
];
allowedUDPPorts = lib.optionals (lib.elem "squeezelite" cfg.providers) [
# https://lyrion.org/reference/slimproto-protocol/
3483 # Slimproto discovery
];
# The information published by Apple 1 seem to not apply to libraop.
# The closest we could find that represents the port range being used as observed by tcpdump is the ephemeral port range.
# 1: https://support.apple.com/en-us/103229#:~:text=49152%E2%80%93-,65535,-TCP%2C%20UDP
# 2: https://en.wikipedia.org/wiki/Ephemeral_port#Range
allowedUDPPortRanges = lib.mkIf (lib.elem "airplay" cfg.providers) [
{
from = 32768;
to = 65535;
}
];
};
services = {
avahi = lib.mkIf (lib.elem "airplay_receiver" cfg.providers) {
enable = true;
openFirewall = lib.mkIf cfg.openFirewall true;
publish = {
enable = true;
userServices = true;
};
};
music-assistant.providers = cfg.package.providersBuiltins;
};
systemd.services.music-assistant = {
description = "Music Assistant";
documentation = [ "https://music-assistant.io" ];
after = [ "network-online.target" ];
wants = [ "network-online.target" ];
wantedBy = [ "multi-user.target" ];
environment = {
HOME = "/var/lib/music-assistant";
PYTHONPATH = finalPackage.pythonPath;
};
path =
with pkgs;
[
lsof
]
++ lib.optionals (lib.elem "airplay" cfg.providers) [
cliairplay
libraop
]
++ lib.optionals (lib.elem "airplay_receiver" cfg.providers) [
shairport-sync
]
++ lib.optionals (lib.elem "spotify" cfg.providers) [
librespot-ma
]
++ lib.optionals (lib.elem "spotify_connect" cfg.providers) [
go-librespot
]
++ lib.optionals (lib.elem "snapcast" cfg.providers) [
snapcast
]
++ lib.optionals useYTMusic [
deno
ffmpeg-headless
];
serviceConfig = {
ExecStart = utils.escapeSystemdExecArgs (
[
(lib.getExe cfg.package)
]
++ cfg.extraOptions
);
DynamicUser = true;
StateDirectory = "music-assistant";
AmbientCapabilities = "";
CapabilityBoundingSet = [ "" ];
DevicePolicy = "closed";
LockPersonality = true;
# breaks pyopenssl's cffi calls, used in remote access feature
# not compatible with llvmlite which is required by numba -> librosa
MemoryDenyWriteExecute = false;
# required for torch to properly detect the supported engines
# allows Music-Assistant to warn, if x86_64-v2 cpu features are missing
BindReadOnlyPaths = [ "/proc/cpuinfo" ];
ProcSubset = "all";
ProtectClock = true;
ProtectControlGroups = true;
ProtectHome = true;
ProtectHostname = true;
ProtectKernelLogs = true;
ProtectKernelModules = true;
ProtectKernelTunables = true;
ProtectProc = "invisible";
RestrictAddressFamilies = [
"AF_INET"
"AF_INET6"
"AF_NETLINK"
]
++ lib.optionals (lib.elem "snapcast" cfg.providers) [
"AF_UNIX"
];
RestrictNamespaces = true;
RestrictRealtime = true;
SystemCallArchitectures = "native";
SystemCallFilter = [
"@system-service"
"~@privileged"
"mbind"
]
++ lib.optionals useYTMusic [
"@pkey"
];
RestrictSUIDSGID = true;
UMask = "0077";
};
};
};
}
|
