nixos/modules/programs/nautilus-open-any-terminal.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{
  config,
  lib,
  pkgs,
  ...
}:

let
  cfg = config.programs.nautilus-open-any-terminal;
in
{
  options.programs.nautilus-open-any-terminal = {
    enable = lib.mkEnableOption "nautilus-open-any-terminal";

    terminal = lib.mkOption {
      type = with lib.types; nullOr str;
      default = null;
      description = ''
        The terminal emulator to add to context-entry of nautilus. Supported terminal
        emulators are listed in <https://github.com/Stunkymonkey/nautilus-open-any-terminal#supported-terminal-emulators>.
      '';
    };
  };

  config = lib.mkIf cfg.enable {
    environment.systemPackages = with pkgs; [
      nautilus-python
      nautilus-open-any-terminal
    ];

    environment.sessionVariables = lib.mkIf (!config.services.desktopManager.gnome.enable) {
      NAUTILUS_4_EXTENSION_DIR = "${pkgs.nautilus-python}/lib/nautilus/extensions-4";
    };

    environment.pathsToLink = [
      "/share/nautilus-python/extensions"
    ];

    programs.dconf = lib.optionalAttrs (cfg.terminal != null) {
      enable = true;
      profiles.user.databases = [
        {
          settings."com/github/stunkymonkey/nautilus-open-any-terminal".terminal = cfg.terminal;
          lockAll = true;
        }
      ];
    };
  };
  meta = {
    maintainers = with lib.maintainers; [
      stunkymonkey
      linsui
    ];
  };
}