nixos/modules/programs/kde-pim.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

{
  config,
  lib,
  pkgs,
  ...
}:

let
  cfg = config.programs.kde-pim;
in
{
  options.programs.kde-pim = {
    enable = lib.mkEnableOption "KDE PIM base packages";
    kmail = lib.mkEnableOption "KMail";
    kontact = lib.mkEnableOption "Kontact";
    merkuro = lib.mkEnableOption "Merkuro";
  };

  config = lib.mkIf cfg.enable {
    environment.systemPackages =
      with pkgs.kdePackages;
      [
        # core packages
        akonadi
        kdepim-runtime
      ]
      ++ lib.optionals cfg.kmail [
        akonadiconsole
        akonadi-search
        kmail
        kmail-account-wizard
      ]
      ++ lib.optionals cfg.kontact [
        kontact
      ]
      ++ lib.optionals cfg.merkuro (
        [
          merkuro
        ]
        # Only needed when using the Merkuro Contacts widget in Plasma.
        ++ lib.optionals config.services.desktopManager.plasma6.enable [
          kcontacts
          akonadi-contacts
        ]
      );
  };
}