nixos/modules/programs/browserpass.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

{
  config,
  lib,
  pkgs,
  ...
}:

{

  options.programs.browserpass.enable = lib.mkEnableOption "Browserpass native messaging host";

  config = lib.mkIf config.programs.browserpass.enable {
    environment.etc =
      let
        appId = "com.github.browserpass.native.json";
        source = part: "${pkgs.browserpass}/lib/browserpass/${part}/${appId}";
      in
      {
        # chromium
        "chromium/native-messaging-hosts/${appId}".source = source "hosts/chromium";
        "chromium/policies/managed/${appId}".source = source "policies/chromium";

        # chrome
        "opt/chrome/native-messaging-hosts/${appId}".source = source "hosts/chromium";
        "opt/chrome/policies/managed/${appId}".source = source "policies/chromium";

        # vivaldi
        "opt/vivaldi/native-messaging-hosts/${appId}".source = source "hosts/chromium";
        "opt/vivaldi/policies/managed/${appId}".source = source "policies/chromium";

        # brave
        "opt/brave/native-messaging-hosts/${appId}".source = source "hosts/chromium";
        "opt/brave/policies/managed/${appId}".source = source "policies/chromium";
      };
    programs.firefox.nativeMessagingHosts.packages = [ pkgs.browserpass ];
  };
}