blob: cc27e46fcc7d01f1b4f1403861e22ea826e77572 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
{
config,
pkgs,
lib,
...
}:
let
cfg = config.programs._1password-gui;
in
{
imports = [
(lib.mkRemovedOptionModule [ "programs" "_1password-gui" "gid" ] ''
A preallocated GID will be used instead.
'')
];
options = {
programs._1password-gui = {
enable = lib.mkEnableOption "the 1Password GUI application";
polkitPolicyOwners = lib.mkOption {
type = lib.types.listOf lib.types.str;
default = [ ];
example = lib.literalExpression ''["user1" "user2" "user3"]'';
description = ''
A list of users who should be able to integrate 1Password with polkit-based authentication mechanisms.
'';
};
package =
lib.mkPackageOption pkgs "1Password GUI" {
default = [ "_1password-gui" ];
}
// {
apply =
pkg:
pkg.override {
inherit (cfg) polkitPolicyOwners;
};
};
};
};
config = lib.mkIf cfg.enable {
environment.systemPackages = [ cfg.package ];
users.groups.onepassword.gid = config.ids.gids.onepassword;
security.wrappers = {
"1Password-BrowserSupport" = {
source = "${cfg.package}/share/1password/1Password-BrowserSupport";
owner = "root";
group = "onepassword";
setuid = false;
setgid = true;
};
};
};
}
|
