nixos/modules/hardware/ksm.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

{ config, lib, ... }:
let
  cfg = config.hardware.ksm;

in
{
  imports = [
    (lib.mkRenamedOptionModule [ "hardware" "enableKSM" ] [ "hardware" "ksm" "enable" ])
  ];

  options.hardware.ksm = {
    enable = lib.mkEnableOption "Linux kernel Same-Page Merging";
    sleep = lib.mkOption {
      type = lib.types.nullOr lib.types.int;
      default = null;
      description = ''
        How many milliseconds ksmd should sleep between scans.
        Setting it to `null` uses the kernel's default time.
      '';
    };
  };

  config = lib.mkIf cfg.enable {
    systemd.services.enable-ksm = {
      description = "Enable Kernel Same-Page Merging";
      wantedBy = [ "multi-user.target" ];
      script = ''
        echo 1 > /sys/kernel/mm/ksm/run
      ''
      + lib.optionalString (cfg.sleep != null) ''
        echo ${toString cfg.sleep} > /sys/kernel/mm/ksm/sleep_millisecs
      '';
    };
  };
}