blob: d179c9090dad064cb13d64187fb0ab66eeca49c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
{
config,
lib,
options,
...
}:
let
inherit (lib) types mkOption literalMD;
# Approximate position of meta.teams / meta.maintainers in nixos tests.
# Right now this assumes only one such position and ignores other definitions.
# FIXME allow having multiple `maintainersPosition` et al..
getPosition =
definitionsWithLocations:
if definitionsWithLocations == [ ] then
null
else
{
file = (lib.head definitionsWithLocations).file;
column = 0;
line = 1;
};
in
{
options = {
meta = mkOption {
description = ''
The [`meta`](https://nixos.org/manual/nixpkgs/stable/#chap-meta) attributes that will be set on the returned derivations.
Not all [`meta`](https://nixos.org/manual/nixpkgs/stable/#chap-meta) attributes are supported, but more can be added as desired.
'';
apply = lib.filterAttrs (k: v: v != null);
type = types.submodule (
{ options, ... }:
{
options = {
maintainers = mkOption {
type = types.listOf types.raw;
default = [ ];
description = ''
The [list of maintainers](https://nixos.org/manual/nixpkgs/stable/#var-meta-maintainers) for this test.
'';
};
maintainersPosition = mkOption {
internal = true;
readOnly = true;
type = types.nullOr types.attrs;
default = getPosition options.maintainers.definitionsWithLocations;
};
teams = mkOption {
type = types.listOf types.raw;
default = [ ];
description = ''
The [list of maintainer-teams](https://nixos.org/manual/nixpkgs/stable/#var-meta-teams) for this test.
'';
};
teamsPosition = mkOption {
internal = true;
readOnly = true;
type = types.nullOr types.attrs;
default = getPosition options.teams.definitionsWithLocations;
};
timeout = mkOption {
type = types.nullOr types.int;
default = 3600; # 1 hour
description = ''
The [{option}`test`](#test-opt-test)'s [`meta.timeout`](https://nixos.org/manual/nixpkgs/stable/#var-meta-timeout) in seconds.
'';
};
broken = mkOption {
type = types.bool;
default = false;
description = ''
Sets the [`meta.broken`](https://nixos.org/manual/nixpkgs/stable/#var-meta-broken) attribute on the [{option}`test`](#test-opt-test) derivation.
'';
};
platforms = mkOption {
type = types.listOf types.raw;
default = lib.platforms.linux ++ lib.optionals (config.containers == { }) lib.platforms.darwin;
defaultText = literalMD ''
`lib.platforms.linux ++ lib.platforms.darwin` when no containers are configured; otherwise `lib.platforms.linux`.
'';
description = ''
Sets the [`meta.platforms`](https://nixos.org/manual/nixpkgs/stable/#var-meta-platforms) attribute on the [{option}`test`](#test-opt-test) derivation.
'';
};
hydraPlatforms = mkOption {
type = types.listOf types.raw;
# Ideally this would default to `platforms` again:
# default = config.platforms;
default = lib.platforms.linux;
defaultText = literalMD "`lib.platforms.linux` only, as the `hydra.nixos.org` build farm does not currently support virtualisation on Darwin.";
description = ''
Sets the [`meta.hydraPlatforms`](https://nixos.org/manual/nixpkgs/stable/#var-meta-hydraPlatforms) attribute on the [{option}`test`](#test-opt-test) derivation.
'';
};
};
}
);
default = { };
};
};
}
|
